How to calculate wheel torque from engine torque

Wheel torque can be calculated function of engine torque if the parameters and status of the transmission are known. In this tutorial, we are going to calculate the wheel torque and force for a given:

• engine torque
• gear ratio (of the engaged gear)
• final drive ratio (at the differential)
• (free static) wheel radius

Also, we are going to assume that there is no slip in the clutch or torque converter, the engine being mechanically linked to the wheels.

This method can be applied to any powertrain architecture (front-wheel drive or rear-wheel drive) but, for an easier understanding of the components, we are going to use a read-wheel drive (RWD) powertrain.

As depicted in the image above, the engine is the source of torque. The gearbox is connected to the engine through the clutch (on a manual transmissions) or torque converter (on an automatic transmissions). We consider that there is absolutely no slip in the clutch (fully closed) or in the torque converter (lock-up clutch closed). In this case the engine torque T_e [Nm] is equal with the clutch/torque converter torque T_c [Nm].

\[T_c = T_e \tag{1}\]

Further, the engine torque is transmitted through the gearbox, where is multiplied with the gear ratio of the engaged gear i_x [-] and outputs the gearbox torque T_g [Nm].

\[T_g = i_x \cdot T_e \tag{2}\]

The propeller shaft is transmitting the torque to the rear axle, where is multiplied with the final drive gear ratio i₀ [-]. This gives the torque at the differential T_d [Nm].

\[T_d = i_0 \cdot T_g \tag{3}\]

If the vehicle is driven on a straight line, the torque at the differential is equally split between the left wheel T_lw [Nm] and the right wheel T_rw [Nm].

\[T_{lw} = T_{rw} = \frac{T_d}{2} \tag{4}\]

The sum of the left and right wheel torque gives the torque at the differential.

\[T_{lw} + T_{rw} =T_d \tag{5}\]

Replacing (2) in (3) in (4) gives the mathematical expression of the wheel torque function of the engine torque, for a given gearbox ratio i_x and a final drive ratio i₀.

\[\bbox[#FFFF9D]{T_w = \frac{i_x \cdot i_0 \cdot T_e}{2} }\tag{6}\]

If we consider n_w [-] as the number of driving wheels, then the wheel torque formula will have the general form of:

\[\bbox[#FFFF9D]{T_w = \frac{i_x \cdot i_0 \cdot T_e}{n_{w}} }\tag{6.1}\]

If the vehicle is rear wheel drive (RWD) or front wheel drive (FWD) then n_w = 2, if the vehicle is four wheel drive (4WD) or all wheel drive (AWD) the n_w = 4. If the vehicle is a motorcycle then n_w = 1.

The formula of the wheel torque (6) applies to a vehicle which is driven on a straight line, where the left wheel torque is equal with the right wheel torque.

\[T_{lw} = T_{rw} = T_w \tag{7}\]

From mechanics (static), we know that the torque is the product between a force and its lever arm length. In our case, the wheel torque is applied in the wheel hub (center) and the lever arm is the wheel radius r_w [m]. For this example we assume that both wheel have the same radius r_w.

\[T_{lw} = F_{lw} \cdot r_w \tag{8}\]

The same principle applies to the right wheel torque.

\[T_{rw} = F_{rw} \cdot r_w \tag{9}\]

Assuming that both left and right wheel torque and radius are equal, we can write a generic expression of the wheel force F_w [N], function of wheel torque T_w [Nm] and wheel radius r_w [m].

\[T_{w} = F_{w} \cdot r_w \tag{10}\]

From (10) we can extract the formula of the wheel force function of the wheel torque and wheel radius.

\[\bbox[#FFFF9D]{F_{w} = \frac{T_w}{r_w}} \tag{11}\]

Replacing (6) in (10) will give the mathematical expression of the wheel force function of engine torque, gearbox gear ratio, final drive ratio and wheel radius.

\[\bbox[#FFFF9D]{F_{w} = \frac{i_x \cdot i_0 \cdot T_e}{2 \cdot r_w}} \tag{12}\]

For a different number of driving wheels n_w [-], the general formula for wheel force becomes:

\[\bbox[#FFFF9D]{F_{w} = \frac{i_x \cdot i_0 \cdot T_e}{n_{w} \cdot r_w}} \tag{12.1}\]

Example 1. Calculate the wheel torque and force for a rear wheel drive vehicle (RWD) with the following parameters:

• engine torque, T_e = 150 Nm
• gearbox (1^st) gear ratio, i_x = 4.171
• final drive ratio, i₀ = 3.460
• tire size marking 225/55R17

Step 1. Calculate the (free static) wheel radius from the tire size marking. The method for calculating the wheel radius is described in the article How to calculate wheel radius. The calculated wheel radius is r_w = 0.33965 m.

Step 2. Calculate the wheel torque using equation (6).

\[T_w = \frac{i_x \cdot i_0 \cdot T_e}{2} = \frac{4.171 \cdot 3.460 \cdot 150}{2} = 1082.3745 \text{ Nm}\]

Step 3. Calculate the wheel force using equation (11).

\[F_{w} = \frac{T_w}{r_w} = \frac{1082.3745}{0.33965} = 3186.7349 \text{ N} \]

Example 2. For a given gearbox, with multiple gears (gear ratios), we can calculate the wheel torque and force for each gear. Let’s calculate the wheel torque and force for a vehicle with the following parameters:

• engine torque, T_e = 150 Nm
• wheel radius, r_w = 0.33965 m

The gearbox is automatic (ZF6HP26), with the following gear ratios and final drive ratio.

Gear #	Gear ratio symbol	Gear ratio
1	i1	4.171
2	i2	2.340
3	i3	1.521
4	i4	1.143
5	i5	0.867
6	i6	0.691
Final drive	i0	3.460

To speed up calculations, we can use a Scilab script.

clc
// Input data
Te = 150;
ix = [4.171 2.340 1.521 1.143 0.867 0.691];
i0 = 3.460;
rw = 0.33965;
nw = 2;

// Wheel torque and force calculation
Tw = (ix .* i0 .* Te)/nw;
Fw = Tw ./ rw;

// Display results
mprintf("\n%s\t\t%s\t\t%s\t\t%s\n","Gear","ix [-]","Tw [Nm]","Fw [N]")
for i=1:length(ix)
    mprintf("%d\t\t%.3f\t\t%.2f\t\t%.2f\n",i,ix(i),Tw(i),Fw(i));
end

Executing the above script will output the following results in the Scilab console:

Gear		ix [-]		Tw [Nm]		Fw [N]
1		4.171		1082.37		3186.73
2		2.340		607.23		1787.81
3		1.521		394.70		1162.08
4		1.143		296.61		873.28
5		0.867		224.99		662.41
6		0.691		179.31		527.94

Example 3. For our third example we are going to use the full load torque curve of an engine and calculate the wheel torque and force (traction) in each gear. Calculate the wheel torque and force (traction) for a vehicle with the following parameters:

• engine torque, T_e = 150 Nm
• wheel radius, r_w = 0.33965 m
• the gear ratios of ZF6HP26 (see Example 2)

The engine torque at full load is given by the following parameters:

Ne [rpm]	800	1312	1800	2276	2800	3316	3806	4300	4770	5300	5800	6300
Te [Nm]	116	135	148	157	165	172	178	184	188	187	183	171

Since we need to perform a lot of calculations, we’ll use a Scilab script to calculate the wheel torque and force curves for each gear. The results are going to be plotted in a graphical window.

clc
// Input data
Ne = [800 1312 1800 2276 2800 3316 3806 4300 4770 5300 5800 6300];
Te = [116 135 148 157 165 172 178 184 188 187 183 171];
ix = [4.171 2.340 1.521 1.143 0.867 0.691];
i0 = 3.460;
rw = 0.33965;
nw = 2;

// Plot engine torque
figure(1)
hf = gcf();
hf.background = 8;
plot(Ne,Te,"LineWidth",2)
xgrid()
xlabel("Engine speed [rpm]","FontSize",3)
ylabel("Engine torque [Nm]","FontSize",3)
title("x-engineer.org","Color","blue","FontSize",2)

// Calculate wheel torque and force
for i = 1:length(ix)
    for j = 1:length(Te)
        Tw(i,j) = (ix(i) .* i0 .* Te(j))/nw;
        Fw(i,j) = Tw(i,j) ./ rw;
    end
end

// Plot wheel torque and force
figure(2)
hf = gcf();
hf.background = 8;
plot(Ne,Tw,"LineWidth",2)
xgrid()
xlabel("Engine speed [rpm]","FontSize",3)
ylabel("Wheel torque [Nm]","FontSize",3)
title("x-engineer.org","Color","blue","FontSize",2)
legend("1st gear","2nd gear","3rd gear","4th gear","5th gear","6th gear",2)

figure(3)
hf = gcf();
hf.background = 8;
plot(Ne,Fw,"LineWidth",2)
xgrid()
xlabel("Engine speed [rpm]","FontSize",3)
ylabel("Wheel force [N]","FontSize",3)
title("x-engineer.org","Color","blue","FontSize",2)
legend("1st gear","2nd gear","3rd gear","4th gear","5th gear","6th gear",2)

Executing the script will output the following graphical windows.

The same method can be applied for an electric vehicle, the engine torque being replaced by the motor torque.

You can also check your results using the calculator below.

Wheel torque calculator

Te [Nm]	ix [-]	i0 [-]	rw [m]	nw [-]
Calculate wheel torque and force
Tw [Nm] =
Fw [N] =

Don’t forget to Like, Share and Subscribe!