Electric Vehicle Motor Torque and Power Curves

Table of Contents

• Definition
• Main Parameters
• Example
• Equations
• Curves Calculation
• Summary

Definition

A motor torque curve is a graphical representation that shows the relationship between the torque a motor produces and its rotational speed [rpm]. Torque, measured in units like Newton-meters [Nm] or pound-feet [lb-ft], refers to the motor’s ability to generate rotational force, while the speed is how fast the motor’s output shaft is rotating.

For an automotive application, the torque curve is important for the following reasons:

• performance evaluation: the torque curve helps in understanding how a motor performs under various load conditions
• application matching: different applications require different torque characteristics, so the curve helps engineers select the right motor for specific tasks (e.g., a high torque for heavy loads or high speed for fast applications)

A motor power curve is a graphical representation that shows the relationship between the output power of a motor and its rotational speed [rpm]. Power, usually measured in watts [W] or horsepower [HP], is a measure of the motor’s ability to do work over time. It is directly related to both torque and speed, since power is the product of torque and angular velocity.

For an automotive application, the power curve is important for the following reasons:

• optimal operating range: the power curve helps identify the range where the motor operates most efficiently and can deliver the required output for an application
• system matching: just as the torque curve is important for determining motor suitability, the power curve helps match the motor to systems that require specific power outputs over a range of speeds

Go back

Main Parameters

The image below depicts the torque and power curves of an electric motor as functions of rotational speed. It highlights the critical operating regions, including constant torque, field weakening, and constant power. In the low-speed range, the motor delivers maximum torque, essential for applications requiring high force. As speed increases beyond the base speed, the motor enters a field weakening zone, where torque decreases but constant power is maintained, allowing for higher speeds.

The maximum torque T_max of the electric motor is the highest torque the motor can produce and it depends on the rotational speed of the rotor. From standstill (0 rad/s) up to base speed ω_base, the maximum torque is constant. Beyond base speed, the maximum torque starts to decrease and reaches minim value at maximum rotor speed ω_max.

Electric motors manufactures will publish in the technical specification of the electric motor, 2 curves (set of values) for the maximum torque:

• peak torque: this is the maximum motor torque which can be sustained only for a limited amount of time (e.g. 30 s); beyond this time the motor might be damaged due to thermal overloading caused by the high stator currents.
• continuous torque: this is the maximum motor torque which can be sustained for an indefinite amount of time without damaging the electric motor.

Field weakening is a method used to increase the operating speed of the electric motor beyond the rated (base) speed. In Permanent Magnet Synchronous Motors (PMSMs), field weakening involves reducing the magnetic field produced by the rotor by adjusting the current in the stator windings. Since the rotor’s the magnetic field is constant, the weakening effect is achieved indirectly by manipulating the stator currents, which can create a magnetic field opposing that of the rotor’s permanent magnets, effectively reducing the net magnetic field interacting with the rotor.

Field weakening enables the motor to extend its speed range at the cost of reduced torque capability.

P_max is the maximum power output the motor can deliver, shown by the flat section of the power curve after the base speed. The motor reaches this maximum power as it ramps up in speed. From base speed to maximum speed, the motor operates in the constant power region. This means that while the torque decreases with increasing speed, the maximum power output is maintained. This is critical in applications where high speeds are necessary, even if the torque is lower.

Go back

Example

The image below is contains the maximum torque curves (peak and continuos) for a real electric motor.

The motor output torque curves are represented function of motor speed and different input stator voltage. It highlights the critical operating regions, including constant torque, field weakening, and constant power. In the low-speed range, the motor delivers maximum torque, essential for applications requiring high force. As speed increases beyond the base speed, the motor enters a field weakening zone, where torque decreases but constant power is maintained, allowing for higher speeds.

The image above depicts a set of torque curves for the HVH250-115 electric motor at different voltage levels [350V, 500V, 600V, 700V], plotted against motor speed [rpm]. The graph illustrates how the motor’s shaft torque changes across different operating speeds for both peak and continuous torque conditions.

Represented by solid lines, the peak torque curves show the maximum torque the motor can deliver for short periods of time at each voltage level. The higher the voltage, the higher the base speed, the higher the peak torque window. The peak torque remains relatively constant at low speeds, then begins to drop significantly as the motor reaches higher motor speeds. Peak torque is used for short-duration, high-load conditions, but cannot be sustained continuously without overheating or damaging the motor.

Dashed lines indicate the continuous torque the motor can deliver indefinitely without damage. Continuous torque is always lower than peak torque and decreases more steadily as motor speed increases. Again, higher voltages enable higher continuous torque values at higher motor speed.

The image below shows the motor power output curves of the same electric motor across different voltages [350V, 500V, 600V, and 700V], with motor power [kW] plotted against motor speed [rpm]. The graph depicts both peak power and continuous power curves for each voltage level.

The solid lines represent the maximum power the motor can deliver for short periods (peak power) at each voltage level. Power increases rapidly with motor speed and reaches its maximum value (at around 3000-6000 rpm), followed by a gradual decline. This drop at high speed is typical due to the decrease in torque as the motor reaches high speeds.

The dashed lines indicate the motor’s continuous power, or the amount of power the motor can sustain without overheating or wear for long-term operation. Continuous power curves generally follow a similar trend to peak power curves, but the values are lower, as continuous operation demands less strain on the motor

These curves are used by engineers in selecting the right motor for specific applications, ensuring the motor meets both peak (boost) and continuous operational demands.

Go back

Equations

To convert motor speed from [rad/s] to [rpm], we can use the following equation:

N [rpm] = (30 · ω [rad/s]) / π [rad]

To convert motor speed from [rpm] to [rad/s], we can use the inverted equation:

ω [rad/s] = (π [rad] · N [rpm]) / 30

Motor power [kW] can be calculated by multiplying the motor torque [Nm] and motor speed [rad/s], adjusting for the units of measurement, with this equation:

P [kW] = (T [Nm] · ω [rad/s]) / 1000

Go back

Curves Calculation

Based on the following input data of an electric motor:

• continuous power P_cont = 95 kW
• peak torque T_peak = 375 Nm
• minimum speed N_min = 0 rpm
• maximum speed N_max = 12000 rpm
• base speed N_base = 5000 rpm

1. Calculate the continuous torque T_cont [Nm] and the peak power P_peak [kW].
2. Using a Scilab script generate the continuous and peak curves for torque and power. Plot the generated values against motor speed.

1. Numerical Solution

The continuous torque is calculated as (rounded to the highest integer):

T_cont = (P_cont · 1000) / (N_base · π / 30) = (95 · 1000) / (5000 · π / 30) = 182 Nm

The peak power is calculated as (rounded to the highest integer):

P_peak = T_peak · (N_base · π / 30) · 0.001 = 375 · (5000 · π / 30) · 0.001 = 197 kW

2. Scilab Script

clear
clc

// Input data
Pcont = 95       // kW
Tpeak = 375      // Nm
Nmin = 0         // rpm
Nmax = 17000     // rpm
Nbase = 5000     // rpm
dN = 100         // rpm

// Calculate continuous toque and peak power
Tcont = ceil(Pcont*1e3)/(Nbase*%pi/30)     // Nm
Ppeak = ceil(Tpeak*(Nbase*%pi/30)*1e-3)    // kW

// Calculate the slope(s) for power curve(s)
slopePpeak = Ppeak/Nbase                      // kW/rpm
slopePcont = Pcont/Nbase                      // kW/rpm

// Generate the EM speed array
N_x = Nmin:dN:Nmax                            // rpm

// Generate the EM power curves
for i=1:length(N_x)
    if N_x(i) <= Nbase
        Ppeak_y(i) = N_x(i)*slopePpeak        // kW
        Pcont_y(i) = N_x(i)*slopePcont        // kW
    else
        Ppeak_y(i) = Ppeak                    // kW
        Pcont_y(i) = Pcont                    // kW
    end
end

// Geenrate the EM torque curves
for i=1:length(N_x)
    if N_x(i) <= Nbase
        Tpeak_y(i) = Tpeak                    // Nm
        Tcont_y(i) = Tcont                    // Nm
    else
        Tpeak_y(i) = (Ppeak_y(i)*1e3)/(N_x(i)*%pi/30) // Nm
        Tcont_y(i) = (Pcont_y(i)*1e3)/(N_x(i)*%pi/30) // Nm
    end
end

// Plot torque curves
figure(1)
plot(N_x,Tpeak_y,"b","LineWidth",3)
ha1=gca()
ha1.data_bounds = [Nmin,0;Nmax,400]
hf1=gcf()
hf1.background=-2
xgrid()
plot(N_x,Tcont_y,"b-.","LineWidth",3)
xlabel("Motor speed [rpm]", "FontSize", 3)
ylabel("Motor torque [Nm]", "FontSize", 3)
legend("peak","continuous")

// Plot power curves
figure(2)
plot(N_x,Ppeak_y,"r","LineWidth",3)
ha2=gca()
hf2=gcf()
hf2.background=-2
xgrid()
plot(N_x,Pcont_y,"r-.","LineWidth",3)
xlabel("Motor speed [rpm]", "FontSize", 3)
ylabel("Motor power [kW]", "FontSize", 3)
legend("peak","continuous",4)

Running the Scilab script generates the following plots.

Image: Generated Motor Torque Curves

Image: Generated Motor Power Curves

Go back

Summary

The torque curve illustrates how a motor provides maximum torque at low speeds, which then decreases as speed increases, especially in the field-weakening region. The power curve, on the other hand, shows how power rises sharply with speed, reaching a peak before declining at higher motor speed due to reduced torque.

Graphs of peak and continuous torque and power are examined across various voltage levels (350V, 500V, 600V, and 700V). Higher voltages result in increased peak and continuous torque, as well as greater power output, making them ideal for high-demand applications. The continuous curves reflect the motor’s capacity to sustain performance over time without overheating, while peak curves indicate short-term, high-performance capability.

These insights into motor torque and power behavior are essential for selecting the right motor for industrial applications, electric vehicles, and other scenarios where efficient and sustained performance is critical. Understanding these characteristics helps engineers optimize motor operation for specific tasks, balancing torque, power, and energy efficiency.